盗墓笔记第二季,完美世界有声小说全集

經(jīng)過再次努力，終于完成了自己的比較滿意的版本，大家多批評……

批處理功能：

輸入幾個(gè)參數(shù)，讓批處理代你完成煩瑣的工作吧！遠(yuǎn)程FTP文件到本地計(jì)算機(jī)，你可以拖入開機(jī)啟動(dòng)或任務(wù)計(jì)劃中，定時(shí)下載遠(yuǎn)程的指定數(shù)據(jù)，希望大家多測試，多提意見，多完善，謝謝！上代碼！

舉例說明：

我需要每天早上從服務(wù)器202.33.22.102上下載指定目錄的文件到本機(jī)，那么你需要指定以下幾個(gè)參數(shù)即可

一、遠(yuǎn)程IP，Is not null

二、FTP用戶名,Is not null

三、遠(yuǎn)程密碼,Is not null

四、下載哪個(gè)目錄下的文件，如果是根目錄則輸入點(diǎn)點(diǎn)，即".."(沒有雙引號)

五、子目錄，你可能要下載一個(gè)文件夾下的多個(gè)目錄吧？如果有，請用逗號隔開，如果沒有則什么也不要設(shè)置(包括空格)，文件夾名請間量不要有空格，以免不必要的麻煩，當(dāng)你指定了子目錄時(shí)，程序只會下載該子目錄下的文件，而對再下一級文件夾不做任何操作。

六、本地目錄，請指定一個(gè)已存在的目錄，包括"\"，程序會自動(dòng)在該文件夾下創(chuàng)建和服務(wù)器上相同的文件夾

七、日志記錄文件目錄，也是已存在的。

好了，你現(xiàn)在可以雙擊這個(gè)批處理執(zhí)行操作了！

@echo off
echo ********====================================================== 
echo ********====================================================== 
echo ++++++++  批處理功能： 遠(yuǎn)程數(shù)據(jù)FTP備份到本地
echo ++++++++  Date:  %Date:~0,4%-%Date:~5,2%-%Date:~8,2% 
echo ++++++++  Author:  zc_0101         
echo ++++++++  Email:  zc_0101@163.com
echo ++++++++  QQ：  275374095
echo ++++++++  Mark:
echo ++++++++    請嚴(yán)格按照參數(shù)說明定義參數(shù)，輸入?yún)?shù)
echo ++++++++    請盡量常規(guī)化，不要帶特殊字符包括空格
echo ++++++++    如果文件已存在則跳過，不支持短點(diǎn)續(xù)傳
echo ++++++++    不檢測備份數(shù)據(jù)完整性，用戶可自行修改
echo ++++++++  PS:  轉(zhuǎn)載請注明出處(^_^),謝謝！
echo ********====================================================== 
echo ********====================================================== 
pause

Rem 遠(yuǎn)程IP(請保證開啟Server_U)
Set Remote_IP=103.111.124.123

Rem 遠(yuǎn)程登錄用戶名(如果有批處理符號，請進(jìn)行轉(zhuǎn)義)
Set Remote_User=test

Rem 遠(yuǎn)程登錄密碼(如果有批處理符號，請進(jìn)行轉(zhuǎn)義)
Set Remote_Pwd=FkhVBweos^!Sd4al%%

Rem 遠(yuǎn)程操作目錄,如果是根目錄，請?zhí)顚?.."(無雙引號),否則直接填寫目錄名,如Databaseback
set Remote_Path=Databaseback 

Rem 遠(yuǎn)程要下載的目錄列表(注意:僅下載這些目錄下的文件，不會下載子目錄下的文件)，請用逗號隔開,如果沒有子目錄（確保當(dāng)前目錄下有文件可下載），請什么也不要填寫(包括空格);另：文件夾請不要有空格
Set Remote_Directory=DB_Hxxl,DB_OA,master,model,msdb 

Rem 本地備份目錄，請?zhí)顚懸粋€(gè)已存在的目錄(本程序?qū)詣?dòng)在該目錄下創(chuàng)建和遠(yuǎn)程服務(wù)器上同樣的子目錄,請勿帶"\"斜杠)
Set Local_Path=D:\DBback

Rem 操作日志和臨時(shí)文件存放路徑(請務(wù)必帶上"\"斜杠)
Set Log_Path=D:\


Rem 取得當(dāng)前日期，作為日志文件名稱,本例為日志存放目錄加當(dāng)日日期
set today="%Log_Path%%Date:~0,4%-%Date:~5,2%-%Date:~8,2%-%Time:~0,2%%Time:~3,2%%Time:~6,2%.txt"
echo 正在對您輸入的參數(shù)進(jìn)行基本檢測…………
echo 正在檢測輸入?yún)?shù)…………>%today%
if "%Remote_IP%" EQU "" (
  echo 遠(yuǎn)程IP不能為空！請返回為Remote_IP賦值
  echo 遠(yuǎn)程IP為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_User%" EQU "" (
  echo 遠(yuǎn)程登錄名不能為空！請返回為Remote_User賦值
  echo 遠(yuǎn)程登錄名為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_Pwd%" EQU "" (
  echo 遠(yuǎn)程登錄密碼不能為空！請返回為Remote_Pwd賦值
  echo 遠(yuǎn)程登錄密碼為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_Path%" EQU "" (
  echo 遠(yuǎn)程操作目錄不能為空！請返回為Remote_Path賦值,如果是對根目錄操作，請輸入^(點(diǎn)點(diǎn)^)，即".."
  echo 遠(yuǎn)程操作目錄為空，程序退出。>>%today%
  pause
  exit
)
if "%Remote_Directory%" EQU " " (
  echo 遠(yuǎn)程子目錄有誤！您是否為Remote_Directory誤賦值為空格了？如果沒有子目錄請不要賦值，包括空格。
  echo 遠(yuǎn)程子目錄有誤，程序退出。>>%today%
  pause
  exit
)
if "%Local_Path%\" EQU "" (
  echo 本地操作目錄不能為空！請返回為Local_Path賦值 
  echo 本地操作目錄為空，程序退出。>>%today%
  pause
  exit
)
if "%Log_Path%" EQU "" (
  echo 本地日志存放目錄不能為空！請返回為Log_Path賦值 
  echo 本地日志存放目錄為空，程序退出。>>%today%
  pause
  exit
)
echo 參數(shù)基本檢測通過，準(zhǔn)備執(zhí)行數(shù)據(jù)庫備份
echo 參數(shù)基本檢測通過，數(shù)據(jù)庫備份現(xiàn)在開始>>%today%
echo 今天是%Date%,時(shí)間是：%Time:~0,2%:%Time:~3,2%:%Time:~6,2%,正在執(zhí)行數(shù)據(jù)庫備份…………
echo 今天是%Date%,時(shí)間是：%Time:~0,2%:%Time:~3,2%:%Time:~6,2%,正在執(zhí)行數(shù)據(jù)庫備份…………>>%today%

echo 正在創(chuàng)建生成文件列表的ftp文件，請稍候………
echo 正在創(chuàng)建生成文件列表的ftp文件，請稍候…………>>%today%
ping -n 3 127.1>nul

echo 正在將遠(yuǎn)程登錄用戶名寫入ftp文件…………>>%today%
echo %Remote_User%>%Log_Path%command.txt
echo 正在將遠(yuǎn)程登錄密碼寫入ftp文件…………>>%today%
echo %Remote_Pwd%>>%Log_Path%command.txt
echo 正在將下載方式寫入ftp文件…………>>%today%
echo type Binary>>%Log_Path%command.txt
echo 正在判斷遠(yuǎn)程父目錄是否為根目錄 …………>>%today%
if "%Remote_Path%" NEQ ".." (
  if "%Remote_Path%" NEQ "" (
    echo 正在將進(jìn)入遠(yuǎn)程目錄%Remote_Path%的語句寫入ftp文件…………>>%today%
    echo cd %Remote_Path%>>%Log_Path%command.txt
  )
)
echo 正在判斷遠(yuǎn)程子目錄…………>>%today%
if "%Remote_Directory%" NEQ "" (
  echo 正在將子目錄列表的生成語句寫入ftp文件…………>>%today%
  for %%i in (%Remote_Directory%) do (
     echo 正在將子目錄列表%%i的生成語句寫入ftp文件…………>>%today%
     echo mls %%i %Log_Path%%%i_temp.txt>>%Log_Path%command.txt
  )
) else (
  echo 由于沒有填寫子目錄，則將根目錄下文件列表的生成語句寫入ftp文件…………>>%today%
  echo mls - %Log_Path%FileList_temp.txt>>%Log_Path%command.txt
  
) 
echo close>>%Log_Path%command.txt 
echo quit>>%Log_Path%command.txt
echo 正在對command.txt文件進(jìn)行判斷
if not exist "%Log_Path%command.txt\" (
  if exist "%Log_Path%command.txt" (
    echo %Log_Path%command.txt文件創(chuàng)建成功
    echo %Log_Path%command.txt文件創(chuàng)建成功>>%today%
  ) else (
    echo %Log_Path%command.txt文件創(chuàng)建失敗，程序?qū)⑼顺觥?
    echo %Log_Path%command.txt文件創(chuàng)建失敗，程序退出>>%today%
    pause
    echo exit
  )
) else (
  echo 您輸入的參數(shù)存放日志路徑中有竟然有一個(gè)名為Command.txt的文件夾，請手動(dòng)刪除后，重新運(yùn)行程序。
  echo 您輸入的參數(shù)存放日志路徑中竟然有有一個(gè)名為Command.txt的文件夾,程序退出。>>%today%
  pause
  exit
)

echo 正在執(zhí)行服務(wù)器目錄文件列表創(chuàng)建,請稍候…………
echo 正在執(zhí)行服務(wù)器目錄文件列表創(chuàng)建,請稍候…………>>%today%
ping -n 3 127.1>nul
ftp -i -s:%Log_Path%command.txt %Remote_IP%
echo 正在檢查已創(chuàng)建的服務(wù)器目錄文件列表，請稍候…………
echo 正在檢查已創(chuàng)建的服務(wù)器目錄文件列表，請稍候…………>>%today%
if "%Remote_Directory%" NEQ "" (
  for %%i in (%Remote_Directory%) do (
    if not exist "%Log_Path%%%i.txt\" (
      if exist "%Log_Path%\%%i_temp.txt" (
        mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp1.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\%%i_temp.txt').ReadAll().replace(/\r\n/g, '\n\n'));close()"
        mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp2.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp1.txt').ReadAll().replace(/\r/g, ''));close()"
        mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\%%i.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp2.txt').ReadAll().replace(/\n\n/g, '\r\n'));close()"
      )  
      if exist "%Log_Path%%%i.txt" (
        echo %Log_Path%%%i.txt文件創(chuàng)建成功！
        echo %Log_Path%%%i.txt文件創(chuàng)建成功！>>%today%
      ) else (
        echo 對不起，%Log_Path%%%i.txt文件創(chuàng)建失敗！程序?qū)⑼顺觯?
        echo %Log_Path%%%i.txt文件創(chuàng)建失??！程序終止>>%today%
        pause
        exit      
      )
    ) else (
      echo 您輸入的參數(shù)存放日志路徑%Log_Path%中有竟然有一個(gè)名為%%i.txt的文件夾，請手動(dòng)刪除后，重新運(yùn)行程序。
      echo 您輸入的參數(shù)存放日志路徑%Log_Path%中竟然有有一個(gè)名為%%i.txt的文件夾,程序退出。>>%today%
      pause
      exit
    )
  )
) else (
  if not exist "%Log_Path%FileList.txt\" (
    if exist "%Log_Path%\FileList_temp.txt" (
      mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp1.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\FileList_temp.txt').ReadAll().replace(/\r\n/g, '\n\n'));close()"
      mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\temp2.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp1.txt').ReadAll().replace(/\r/g, ''));close()"
      mshta "javascript:var fso=new ActiveXObject('Scripting.FileSystemObject');fso.OpenTextFile('%Log_Path%\FileList.txt',2,true).Write(fso.OpenTextFile('%Log_Path%\temp2.txt').ReadAll().replace(/\n\n/g, '\r\n'));close()"
    )
    if exist "%Log_Path%FileList.txt" (
    echo %Log_Path%FileList.txt文件創(chuàng)建成功！
      echo %Log_Path%FileList.txt文件創(chuàng)建成功！>>%today%
    ) else (
      echo 對不起，%Log_Path%FileList.txt文件創(chuàng)建失敗！
      echo %Log_Path%FileList.txt文件創(chuàng)建失?。〕绦蚪K止>>%today%
      pause
      exit
    )
  ) else (
    echo 您輸入的參數(shù)存放日志路徑%Log_Path%中有竟然有一個(gè)名為FileList.txt的文件夾，請手動(dòng)刪除后，重新運(yùn)行程序。
    echo 您輸入的參數(shù)存放日志路徑%Log_Path%中竟然有有一個(gè)名為FileList.txt的文件夾,程序退出。>>%today%
    pause
    exit
  )
)

echo 程序開始下載文件，請耐心等待…………
echo 程序開始下載文件，請耐心等待…………>>%today%
if "%Remote_Directory%" NEQ "" (
  for %%i in (%Remote_Directory%) do (
    echo 正在創(chuàng)建目錄%Local_Path%\%%i…………
    echo 創(chuàng)建目錄%Local_Path%\%%i…………>>%today%
    md %Local_Path%\%%i
    echo 正在下載%Remote_Path%\%%i文件夾備份,請稍候…………
    echo 正在下載%Remote_Path%\%%i文件夾備份,請稍候…………>>%today%
    ping -n 3 127.1>nul
    for /f "delims=. tokens=1,2" %%j in (%Log_Path%%%i.txt) do (
      if not exist "%Local_Path%\%%i\%%j.%%k\" (
        if not exist "%Local_Path%\%%i\%%j.%%k" (
          echo 正在創(chuàng)建下載文件%%j.%%k的腳本,請稍候…………
          echo 正在創(chuàng)建下載文件%%j.%%k的腳本,請稍候…………>>%today%
          echo %Remote_User%>%Log_Path%GetFiles.txt
          echo %Remote_Pwd%>>%Log_Path%GetFiles.txt
          echo type Binary>>%Log_Path%GetFiles.txt
          if "%Remote_Path%" NEQ "" (
            if "%Remote_Path%" NEQ ".." ( 
              echo cd %Remote_Path%>>%Log_Path%GetFiles.txt
            )
          )
          echo cd %%i>>%Log_Path%GetFiles.txt
          echo lcd %Local_Path%\%%i>>%Log_Path%GetFiles.txt
          echo mget "%%j.%%k">>%Log_Path%GetFiles.txt
          echo close>>%Log_Path%GetFiles.txt
          echo quit>>%Log_Path%GetFiles.txt
          ftp -i -s:%Log_Path%GetFiles.txt %Remote_IP%
          echo 正在檢查文件%Local_Path%\%%i\%%j.%%k，請稍候……
          echo 正在檢查文件%Local_Path%\%%i\%%j.%%k，請稍候……>>%today%
          if exist "%Local_Path%\%%i\%%j.%%k\" (
            echo ————下載%Local_Path%\%%i\%%j.%%k成功！
            echo ————下載%Local_Path%\%%i\%%j.%%k成功！>>%today%
          ) else (
            echo ——由于未知原因，下載%Local_Path%\%%i\%%j.%%k失敗！
            echo ——由于未知原因，下載%Local_Path%\%%i\%%j.%%k失敗！>>%today%
          )
        ) else (
          echo %Local_Path%\%%i\%%j.%%k已存在，正在跳過————
          echo %Local_Path%\%%i\%%j.%%k已存在，正在跳過————>>%today%
        )
      ) else (
        echo 您輸入的參數(shù)存放備份路徑%Local_Path%\%%i中有竟然有一個(gè)名為%%j.%%k的文件夾，請手動(dòng)刪除后，重新運(yùn)行程序。
        echo 您輸入的參數(shù)存放備份路徑%Local_Path%\%%i中竟然有有一個(gè)名為%%j.%%k的文件夾,程序退出。>>%today%
        pause
        exit
      )
    )
  )
) else (
  echo 由于沒有指定服務(wù)器子目錄，程序?qū)逊?wù)器父目錄下的文件備份到您指定的本地目錄中…………
  echo 由于沒有指定服務(wù)器子目錄，程序?qū)逊?wù)器父目錄下的文件備份到您指定的本地目錄中…………>>%today%
  for /f "delims=. tokens=1,2" %%j in (%Log_Path%FileList.txt) do (
    if not exist "%Local_Path%\%%j.%%k\" (
      if not exist "%Local_Path%\%%j.%%k" (
        echo 正在創(chuàng)建下載文件%%j.%%k的腳本,請稍候…………
        echo 正在創(chuàng)建下載文件%%j.%%k的腳本,請稍候…………>>%today%
        echo %Remote_User%>%Log_Path%GetFiles.txt
        echo %Remote_Pwd%>>%Log_Path%GetFiles.txt
        echo type Binary>>%Log_Path%GetFiles.txt
        if "%Remote_Path%" NEQ "" (
          if "%Remote_Path%" NEQ ".." ( 
            echo cd %Remote_Path%>>%Log_Path%GetFiles.txt
          )
        )
        echo lcd %Local_Path%>>%Log_Path%GetFiles.txt
        echo mget "%%j.%%k">>%Log_Path%GetFiles.txt
        echo close>>%Log_Path%GetFiles.txt
        echo quit>>%Log_Path%GetFiles.txt
        ftp -i -s:%Log_Path%GetFiles.txt %Remote_IP%
        echo 正在檢查文件%Local_Path%\%%j.%%k，請稍候……
        echo 正在檢查文件%Local_Path%\%%j.%%k，請稍候……>>%today%
        if exist "%Local_Path%\%%j.%%k" (
          echo ————下載%Local_Path%\%%j.%%k成功！
          echo ————下載%Local_Path%\%%j.%%k成功！>>%today%
        ) else (
          echo ——由于未知原因，下載%Local_Path%\%%j.%%k失??！
          echo ——由于未知原因，下載%Local_Path%\%%j.%%k失敗！>>%today%
        )
      ) else (
        echo %Local_Path%\%%j.%%k已存在，正在跳過————
        echo %Local_Path%\%%j.%%k已存在，正在跳過————>>%today%
      )
    ) else (
      echo 您輸入的參數(shù)存放備份路徑%Local_Path%\中有竟然有一個(gè)名為%%j.%%k的文件夾，請手動(dòng)刪除后，重新運(yùn)行程序。
      echo 您輸入的參數(shù)存放備份路徑%Local_Path%\中竟然有有一個(gè)名為%%j.%%k的文件夾,程序退出。>>%today%
      pause
      exit
    )
  )
)

echo 程序正在清除臨時(shí)文件，請稍候…………
set temp_str=command.txt,temp1.txt,temp2.txt,GetFiles.txt
for %%i in (%temp_str%) do (
  echo 程序?qū)h除%Log_Path%%%i文件…………>>%today%
  del %Log_Path%%%i
  if exist "%Log_Path%%%i" (
    echo %Log_Path%%%i文件刪除失敗，程序繼續(xù)運(yùn)行
    echo %Log_Path%%%i文件刪除失敗，程序繼續(xù)運(yùn)行>>%today%
  ) else (
    echo %Log_Path%%%i文件刪除成功
    echo %Log_Path%%%i文件刪除成功>>%today%
  )
)

echo 程序正在刪除臨時(shí)文件列表文件，請稍候…………
echo 程序正在刪除臨時(shí)文件列表文件，請稍候…………>>%today%
if "%Remote_Directory%" NEQ "" (
  for %%i in (%Remote_Directory%) do (
    Del %Log_Path%%%i.txt,%Log_Path%%%i_temp.txt
    if exist "%Log_Path%%%i.txt" (
      echo %Log_Path%%%i.txt文件刪除失敗，程序繼續(xù)運(yùn)行
      echo %Log_Path%%%i.txt文件刪除失敗，程序繼續(xù)運(yùn)行>>%today%
    ) else (
      echo %Log_Path%%%i.txt文件刪除成功 
      echo %Log_Path%%%i.txt文件刪除成功 >>%today%
    )
  )
) else (
  del %Log_Path%FileList.txt,%Log_Path%FileList_temp.txt
  if exist "%Log_Path%FileList.txt" (
    echo %Log_Path%FileList.txt文件刪除失敗，程序繼續(xù)運(yùn)行
    echo %Log_Path%FileList.txt文件刪除失敗，程序繼續(xù)運(yùn)行>>%today%
  ) else (
    echo %Log_Path%FileList.txt文件刪除成功
    echo %Log_Path%FileList.txt文件刪除成功>>%today%
  )
)
echo 恭喜您，本次備份工作已經(jīng)圓滿完成！詳情請查看%today%日志文件！
echo 恭喜您，本次備份工作已經(jīng)圓滿完成！>>%today%
echo 數(shù)據(jù)已被備份到%Local_Path%\目錄中。>>%today%
echo 完成時(shí)間：%Time:~0,2%:%Time:~3,2%:%Time:~6,2%>>%today%
pause
exit

您可能感興趣的文章:

批處理(ftp)上傳文件到服務(wù)器的代碼
批處理向FTP上傳具有指定屬性的文件(增量備份)
批處理下載FTP服務(wù)器上指定分鐘數(shù)之前的文件
批處理bat下載FTP服務(wù)器上指定天數(shù)之前的文件
通過批處理修改FTP賬號和密碼
實(shí)現(xiàn)FTP整站上傳的批處理代碼
實(shí)現(xiàn)FTP整站上傳的批處理代碼
批處理bat下載FTP服務(wù)器上某個(gè)目錄下的文件

標(biāo)簽：蕪湖株洲白銀臺州樂山江西公主嶺三門峽

巨人網(wǎng)絡(luò)通訊聲明：本文標(biāo)題《批處理完美實(shí)現(xiàn)FTP遠(yuǎn)程備份數(shù)據(jù)》，本文關(guān)鍵詞批處理,完美,實(shí)現(xiàn),FTP,遠(yuǎn)程,；如發(fā)現(xiàn)本文內(nèi)容存在版權(quán)問題，煩請?zhí)峁┫嚓P(guān)信息告之我們，我們將及時(shí)溝通與處理。本站內(nèi)容系統(tǒng)采集于網(wǎng)絡(luò)，涉及言論、版權(quán)與本站無關(guān)。