因?yàn)橐祷乇韺ο?，無論后續(xù)用什么方法返回，都先要聲明全局type；并且，字段變量類型要為object，不能為record：
create or replace type t_test as object(
EMPNO NUMBER(4),
ENAME VARCHAR2(10),
JOB VARCHAR2(9),
SAL NUMBER(7,2)
);
create or replace type t_test_table as table of t_test;
至于返回表對象的方法，目前發(fā)現(xiàn)三種：
1、用數(shù)組
create or replace function f_test_array(v_deptno in number default null)
return t_test_table
is
v_test t_test_table := t_test_table();
cursor cur is select empno, ename, job, sal from emp where deptno = v_deptno;
begin
for c in cur loop
v_test.extend();
v_test(v_test.count) := t_test(c.empno, c.ename, c.job, c.sal);
end loop;
return v_test;
end;
2、用pipe
create or replace function f_test_pipe(v_deptno in number default null)
return t_test_table PIPELINED
is
v_test t_test_table := t_test_table();
cursor cur is select empno, ename, job, sal from emp where deptno = v_deptno;
begin
for c in cur loop
pipe row(t_test(c.empno, c.ename, c.job, c.sal));
end loop;
return;
end;
這兩種都需要用游標(biāo)遍歷，得到表對象，性能上估計(jì)第2種較高。
3、用collect（不需要游標(biāo)，代碼相對簡單）
create or replace function f_test_collect(v_deptno in number default null)
return t_test_table
is
v_test t_test_table := t_test_table();
begin
select t_test(empno, ename, job, sal) bulk collect into v_test from emp where deptno = v_deptno;
return v_test;
end;
需要注意的是，select into之前要先把輸出結(jié)果對象化：
t_test(empno, ename, job, sal)
否則會報(bào)錯(cuò)：
ORA-00947: 沒有足夠的值(object多字段)
ORA-00932: 數(shù)據(jù)類型不一致（object單一字段）
而如果直接在plsql塊中declare類型的話，是不需要先對象化輸出結(jié)果的。
三種函數(shù)定義方式可以測試輸出一樣的結(jié)果：
select * from table(f_test_pipe(30));
select * from table(f_test_array(30));
select * from table(f_test_collect(30));
以上就是本文的全部內(nèi)容，希望對大家的學(xué)習(xí)有所幫助，也希望大家多多支持腳本之家。
您可能感興趣的文章:- ORACLE 查詢被鎖住的對象，并結(jié)束其會話的方法
- 解析Oracle數(shù)據(jù)庫中的對象集合schema
- oracle查看會話鎖定的所有對象代碼分享
- ORACLE 常用的SQL語法和數(shù)據(jù)對象
- Oracle使用PL/SQL操作COM對象
- 基于Oracle的面向?qū)ο蠹夹g(shù)入門基礎(chǔ)簡析開發(fā)者網(wǎng)絡(luò)Oracle
- PHP 5 數(shù)據(jù)對象 (PDO) 抽象層與 Oracle
- MS-sql 2005拒絕了對對象 ''xxx'' (數(shù)據(jù)庫 ''xxx''，架構(gòu) ''dbo'')的 SELECT 權(quán)限的解決方法
- 重新編譯PLSQL中的無效對象或者指定的對象 的方法
- asp sqlserver 執(zhí)行存儲過程返回記錄集報(bào)對象關(guān)閉時(shí)不允許操作
